本文总共1343个字,阅读需5分钟,全文加载时间:2.234s,本站办公入门专栏收录该内容! 字体大小:

文章导读:COUNTIF函数用于统计满足某个条件的单元格的数量,其基本用法为: COUNTIF(统计区域,指定的条件) 如下图所示,要统计A列有几个5,可以使用以下公式: =COUNTIF(A2:A10,5) 咱们把COUNTIF函数的第二参数稍加改……各位看官请向下阅读:

COUNTIF函数用于统计满足某个条件的单元格的数量,其基本用法为:

COUNTIF(统计区域,指定的条件)

如下图所示,要统计A列有几个5,可以使用以下公式:

=COUNTIF(A2:A10,5)

咱们把COUNTIF函数的第二参数稍加改动,就可以衍生出很多高效用法,例如:

统计大于5的单元格个数:

=COUNTIF(A2:A10,">5")

统计大于B2单元格数值的单元格个数:

=COUNTIF(A2:A10,">"&B2)

统计不等于5的单元格个数:

=COUNTIF(A2:A10,"<>5")

统计空白单元格的个数:

=COUNTIF(A2:A10,"=")

统计非空单元格的个数:

=COUNTIF(A2:A10,"<>")

统计以"e"或“E”开头的单元格个数:

=COUNTIF(A2:A10,"e*")

对于身份证号码以及银行卡号等超长的文本型数字,使用COUNTIF函数时还需要加上一点“佐料”。

以下公式统计A列的身份证号码是否有重复:

=IF(COUNTIF(A:A,A2&"*")>1,"重复","")

COUNTIF函数在计算文本型数字时,会默认按数值型进行处理,但是Excel中的数字精度只有15位,并且身份证号码是18位,因此会把前15位相同的身份证全部识别为相同的内容。

在第二参数后加上一个星号 &"*",就是告诉Excel,要查找包含A2单元格内容的文本,通过这样变通的手段,COUTNIF函数就听话啦。

前面咱们说的是COUNTIF的第二参数,第一参数表示“我不服!”:

以下公式统计A列的姓名是否为首次出现:

=IF(COUNTIF(A$2:A2,A2)=1,"是","否")

这里的第一参数是A$2:A2,第一个A2是锁定的,第二个A2是敞开的,当公式向下复制时,这个范围会不断扩大,变成A$2:A3、A$2:A4、A$2:A5……

COUNTIF函数在这个动态扩展的范围中,统计A列当前行姓名的个数,结果为1,就是首次出现,超过1,就是重复出现了。

以下公式统计A列的姓名是否为最后一次出现:

=IF(COUNTIF(A2:A$10,A2)=1,"是","否")

这里第一参数A2:A$10的用法与上一个例子相反,A$10部分是锁定的,随着公式的下拉,引用范围会不断缩小变成A3:A$10、A4:A$10、A5:A$10……

COUNTIF函数在这个动态缩小的范围中,统计A列当前行姓名的个数,结果是1的话,表示后面一句没有与之相同的内容,OK,这就是最后一次出现了。

如果将COUNTIF函数用到条件格式中,还能将符合条件的内容突出显示,例如,咱们要突出显示重复出现的数据,可以这样操作:

1、选中A2:A10单元格区域,新建格式规则

2、使用公式为:

=COUNTIF(A$2:A2,A2)>1

3、设置突出显示的格式

如果将COUNTIF函数用于数据验证(数据有效性)中,还能限制不准录入重复数据:

1、选中要输入数据的A2:A10单元格区域,【数据】→【数据验证】

2、允许类型选择“自定义”,公式为:

=COUNTIF(A:A,A2)=1

好了,今天咱们的内容就是这些吧,祝各位小伙伴一天好心情!

图文制作:祝洪忠

想要从零系统学习Excel,查看本站上方“视频教程”获取最新秋叶Office三合一办公应用课程!

以上内容由优质教程资源合作伙伴 “鲸鱼办公” 整理编辑,如果对您有帮助欢迎转发分享!

你可能对这些文章感兴趣:

发表评论

您的电子邮箱地址不会被公开。 必填项已用*标注